From 82da31b3e0e9acdfbca4c48eb12ab1f28515ba10 Mon Sep 17 00:00:00 2001
From: Joey Hess <joeyh@debian.org>
Date: Wed, 9 Jul 2014 22:11:31 -0400
Subject: propellor (0.8.1) unstable; urgency=medium

  * Run apt-get update in initial bootstrap.
  * --list-fields now includes a table of fields that are not currently set,
    but would be used if they got set.
  * Remove .gitignore from cabal file list, to avoid build failure on Debian.
    Closes: #754334

# imported from the archive
---
 src/Propellor/Property/Hostname.hs | 39 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 src/Propellor/Property/Hostname.hs

(limited to 'src/Propellor/Property/Hostname.hs')

diff --git a/src/Propellor/Property/Hostname.hs b/src/Propellor/Property/Hostname.hs
new file mode 100644
index 00000000..1cce4e60
--- /dev/null
+++ b/src/Propellor/Property/Hostname.hs
@@ -0,0 +1,39 @@
+module Propellor.Property.Hostname where
+
+import Propellor
+import qualified Propellor.Property.File as File
+
+-- | Ensures that the hostname is set using best practices.
+--
+-- Configures /etc/hostname and the current hostname.
+--
+-- /etc/hosts is also configured, with an entry for 127.0.1.1, which is
+-- standard at least on Debian to set the FDQN.
+--
+-- Also, the /etc/hosts 127.0.0.1 line is set to localhost. Putting any
+-- other hostnames there is not best practices and can lead to annoying
+-- messages from eg, apache.
+sane :: Property
+sane = property ("sane hostname") (ensureProperty . setTo =<< asks hostName)
+
+setTo :: HostName -> Property
+setTo hn = combineProperties desc go
+  where
+	desc = "hostname " ++ hn
+	(basehost, domain) = separate (== '.') hn
+
+	go = catMaybes
+		[ Just $ "/etc/hostname" `File.hasContent` [basehost]
+		, if null domain
+			then Nothing 
+			else Just $ trivial $ hostsline "127.0.1.1" [hn, basehost]
+		, Just $ trivial $ hostsline "127.0.0.1" ["localhost"]
+		, Just $ trivial $ cmdProperty "hostname" [basehost]
+		]
+	
+	hostsline ip names = File.fileProperty desc
+		(addhostsline ip names)
+		"/etc/hosts"
+	addhostsline ip names ls =
+		(ip ++ "\t" ++ (unwords names)) : filter (not . hasip ip) ls
+	hasip ip l = headMaybe (words l) == Just ip
-- 
cgit v1.3-2-g0d8e